地元のおすすめシェアサービス「レシモ」

「地元」のおすすめだけをシェアできるサービスを作りました！

おいしい食べ物をみつけたり、楽しい場所をみつけたら、その場で共有してみてください。

RICOH THETA S のシャッター音を消す・調節する方法

2015年12月3日 DIY iLANDS 野平 0

Pocket

※※ 2015年3月2日更新 ※※

RICOH THETA S 公式アプリでシャッター音量の調節ができるようになりました。
公式アプリを使った音量調整方法についてはこちらの記事をご覧ください。

本日の記事では「RICOH THETA S」のシャッター音を消したり、大きくしたり、はたまた小さくしたりと、お好みの音量に調節できる方法をご紹介します。

RICOH THETA S って何？

ところでみなさんは「RICOH THETA S」という製品をご存知ですか？

Google や Yahoo などの検索エンジンからこの場所に辿り着いた方には釈迦に説法ですが、RICOH THETA S をご存じない方もいらっしゃるかと思いますのでご了承ください。

「RICOH THETA S」は簡潔に述べると・・・

"カシャ" っというワンショットでその場所の 360 度全ての空間を写真や動画に収めることができるカメラ

なんです！

そんな夢のようなカメラ「RICOH THETA S」の外観がこちら。

theta-s-00-body

ボン・キュッ・ボンのセクシーボディではありませんが、このスタイリッシュで高級感のあるボディデザイン！

・・・惚れました。

・・・
・・・
・・・

・・・と、見惚れて余韻に浸ってばかりじゃいられないので、ひとまず見た目は置いておいて「ワンショットでその場所の 360 度全ての空間を撮影できる！」って気になりませんか？？

ということで、百聞は一見に如かず！「RICOH THETA S」で撮影すると次のような写真が撮れるんです。

RICOH THETA S で撮影した写真や動画

この写真は砂蒸し温泉で有名な鹿児島県指宿市にある歩いて渡れる無人島「知林ヶ島」が見渡せる海岸で撮影したものです。

最近は陽が落ちるのが早く、且つ、撮影した時刻が夕暮れ時だったこともあり、日陰の場所がかなり多くなってしまった若干残念な写真ではありますが、とにかく上下左右に動かしてみてください。しっかりと 360 度全ての空間を撮影出来ていて、その場所に行ったように全ての場所を好きなように見渡すことができます。

Post from RICOH THETA. - Spherical Image - RICOH THETA

RICOH THETA の専用サイト(https://theta360.com/)では、「RICOH THETA S」で撮影したサンプル画像として下記のような写真が公開されています。

Birthday Party in Japan - Spherical Image - RICOH THETA

Milky Way from an Norikura Observatory in Mt. Marishiten-dake, Japan - Spherical Image - RICOH THETA

右を見たり、左を見たり、上を見たり、下を見たり、さらにはズームしたりして、色々なところをくまなく見てみたくなる写真です。

この専用サイトには 360 度撮影の動画も公開されているのですが、なんと動画の再生中に上記写真と同じように上下左右を見たり、ズームしたりできるんです！（動画のファイルサイズが大きいためリンクを貼っておきますので気になる方はご体験ください）

https://theta360.com/m/4G2ivD2JeERa2llCHXO4ToTrw

RICOH THETA S の欠点！？

しかし、こんな優れもの「RICOH THETA S」にも、とある欠点が・・・

「RICOH THETA S」には標準でシャッター音の調節機能がないんです。「RICOH THETA S」で撮影すると毎回このような音がします。

周りにそんなに人がいないところでは気にならないのですが、大勢の人が集まった場所などではちょっと気になるところです。

ということで、お待たせしました！ここから本題に戻って「RICOH THETA S のシャッター音を消す・調節する方法」をご紹介します。

RICOH THETA S 技術的なお話

まずはじめに、ほんの少しだけ技術的な話を。

技術的な話はいいから音を消す方法を早く！という方はこちら「RICOH THETA S のシャッター音を消す・調節する方法」にジャンプしてください。

「RICOH THETA S」は製品として販売されているだけでなく、無線(Wi-Fi)経由で「RICOH THETA S」の各種操作を行える「RICOH THETA API v2」(*1)が開発者向けに提供されています。

この API は HTTP 1.1 を利用する OSC プロトコル(Open Spherical Camera API Version 1.0)(*2)に準拠しているので、HTTP サーバを実装する「RICOH THETA S」に対して GET もしくは POST method の HTTP request を投げることで「RICOH THETA S」を操作できるようになっています。

さらに、この API には OSC プロトコル準拠の API に加え、コマンド名やパラメータ名がアンダースコア(_)で始まる vendor-specific な拡張 API が存在します。

OSC プロトコルで規定されている API にはシャッター音の調節機能はないのですが、RICOH 独自の拡張 API (camera.setOptions コマンドの _shutterVolume パラメータ)としてシャッター音の調節機能が提供されていますので、今回は拡張機能を利用して「RICOH THETA S のシャッター音を消す・調節する方法」をご紹介します。

(*1) RICOH THETA API v2 の詳細について知りたい方はこちらのサイト「THETA DEVELOPERS BETA - API Reference」をご覧ください。

(*2) OSC プロトコルの詳細について知りたい方はこちらのサイト「Google Developers - Open Spherical Camera API」をご覧ください。

RICOH THETA S のシャッター音を消す・調節する方法

RICOH THETA S のシャッター音を消したり、調節したりする手順は概ね次のとおりとなります。

cURL オープンソースコマンドのダウンロードとインストール
RICOH THETA S とパソコンの接続
RICOH THETA S のシャッター音を消す・調節する

準備するもの

RICOH THETA S 本体
Wi-Fi が利用可能なパソコン

RICOH THETA S のシャッター音を調節するには、RICOH THETA S とパソコンを Wi-Fi 経由で接続して行いますので、まずはじめにお手元に「RICOH THETA S 本体」と「Wi-Fi が利用可能なパソコン」をご準備ください。

この記事では 64 bit 版 Windows 7 Home Edition (Intel Core i5)のノートパソコンを利用して RICOH THETA S のシャッター音を消す手順をご紹介して参りますが、その他の OS (Mac、Linux、・・・) でも、cURL オープンソースツール(後述)が利用できる OS であれば同じ手順でシャッター音を消すことができます。

cURL のダウンロードとインストール

実際に RICOH THETA S のシャッター音を調節する際は、オープンソースで公開されている cURL コマンドを実行して音量の調節を行います。

この cURL は公式ダウンロードサイト(http://curl.haxx.se/download.html)から入手できますので、このサイトの「Packages」の部分にあるダウンロードリンクより、ご自身の環境(OS)にあった cURL をダウンロードしてください。

theta-s-01-curl-install-01

この記事では前述のとおり 64 bit 版 Windows 7 Home Edition (Intel Core i5)のノートパソコンを使用していますので、「Win64 - Generic」にある「Win64 x86_64 CAB」リンクから cURL をダウンロードします。

theta-s-01-curl-install-02

ダウンロードした cURL 圧縮ファイルを Lhaplus や +Lhaca などの圧縮・解凍ツールを利用して、任意の場所(C:\Program Files\ など)に解凍します。

theta-s-01-curl-install-03

↓　解凍後

theta-s-01-curl-install-05

音量を調節するには解凍したファイル内にある CURL.EXE を利用します。（CURL.EXE があるフォルダの場所はお使いの環境によって異なりますので探してみてください）

theta-s-01-curl-install-06

次に、この CURL.EXE をコマンドラインから手軽に実行できるようにするために、CURL.EXE があるフォルダのパス(例：C:\Program Files\curl-7.45.0\I386)を環境変数 PATH に設定します。

Windows スタートメニューからコントロールパネルを開き「システムとセキュリティ > システム > システムの詳細設定」を選択して表示される「システムのプロパティ」画面の「詳細設定」タブ内にある「環境変数」ボタンを選択します。

theta-s-02-curl-path-01

「システム環境変数」内の「変数」が「Path」となっている行を選択後、「編集」ボタンを選択します。

theta-s-02-curl-path-02

「システム変数の編集」画面が表示されるので、「変数値」入力欄の一番最後に「CURL.EXE があるフォルダのパスの先頭にセミコロン(;)を付与した文字列」（この例では「;C:\Program Files\curl-7.45.0\I386」）を追加後、「OK」を選択します。

theta-s-02-curl-path-03

（注意）PATH を設定する際はすでに設定してある値を間違って消さないようご注意ください。

「環境変数」画面に戻るので「OK」を選択します。

theta-s-02-curl-path-04

「システムのプロパティ」画面に戻るので「OK」を選択します。

theta-s-02-curl-path-05

以上で cURL のダウンロードとインストールは完了です。

ここで CURL.EXE コマンドが使えるようになっているかコマンドプロンプトで確認してみましょう。

Windows スタートメニューから「すべてのプログラム > アクセサリ > コマンドプロンプト」を選択します。「コマンドプロンプト」画面が表示されたら、「curl --help」と入力後「Enter」キーを押します。

theta-s-02-curl-path-06

このように CURL.EXE コマンドのヘルプ画面が表示されたら環境変数 PATH の設定が正常に行われています。

環境変数 PATH の設定が正常に行われていない場合は下記のように「'curl' は、内部コマンドまたは外部コマンド、操作可能なプログラムまたはバッチファイルとして認識されていません。」と表示されますので、CURL.EXE が解凍されているフォルダ名を再確認して環境変数 PATH の設定を行ってください。

theta-s-02-curl-path-07

RICOH THETA S とパソコンの接続

RICOH THETA S とパソコンを無線(Wi-Fi)接続します。

まず RICOH THETA S の電源を入れ、「無線ボタン」を「ON」にしてください。

theta-s-03-connect-theta-01

「無線ボタン」を「ON」にすると RICOH THETA S の正面にある無線ランプが点滅し、無線接続を受け入れられる状態となります。

次にパソコンのツールバー右下に表示されているのネットワークアイコンをクリックすると、RICOH THETA S の無線 LAN (THETAxxxxx.OSC)が表示されるので、RICOH THETA S の無線 LAN をクリックして接続を行います。

theta-s-03-connect-theta-03

RICOH THETA S のシャッター音を消す・調節する

Windows 環境の方はシャッター音を調節できるバッチファイルを準備しましたので、このファイルをダウンロードして任意の場所に解凍してください。

RICOH THETA S のシャッター音を調節するバッチファイル(chthetasvol.zip)

【バッチファイルの中身】

@echo off
rem /*========================================================================*/
rem /* ファイル名 : chthetasvol.bat                                           */
rem /* 使用方法   : DOS> chthetasvol.bat                                      */
rem /* コメント   : chthetasvol.bat を実行することで RICHO THETA S の         */
rem /*              シャッター音量を調節できます。                            */
rem /*              シャッター音量は、下記「変数初期設定」内の「SHUTTER_VOL」 */
rem /*              変数を「0-100」の値で設定します。                         */
rem /*              (注) chthetasvol.bat の実行には事前に curl のインストール */
rem /*                   が必要です。                                         */
rem /*========================================================================*/

rem /*------------------------------------------------------------------------*/
rem /* 変数初期設定                                                           */
rem /*    SHUTTER_VOL   : シャッター音量（0 [小]-100 [大])                    */
rem /*    CMD_CURL      : curl コマンド                                       */
rem /*    IP_THERAS     : THETA S の IP アドレス                              */
rem /*    URL           : THETA S の HTTP 接続 URL                            */
rem /*    OPT_REQMETHOD : HTTP メソッド(curlオプション)                       */
rem /*    OPT_REQHEADER : HTTP ヘッダー(curlオプション)                       */
rem /*    OPT_PROGRESS  : プログレスバー(curlオプション)                      */
rem /*    DATA          : HTTP データ(curlオプション)                         */
rem /*    RESPONSE      : HTTP レスポンス                                     */
rem /*    STATUS        : 各処理の状態(0:正常、他:異常)                       */
rem /*    ERR_MSG       : エラーメッセージ                                    */
rem /*------------------------------------------------------------------------*/

rem /* お好みのシャッター音量（0 [小]-100 [大]) を設定してください。          */
set SHUTTER_VOL=0

rem /* ここから下は変更不要。                                                 */
set CMD_CURL=curl
set IP_THETAS=192.168.1.1
set URL=http://%IP_THETAS%/osc/commands/execute
set OPT_REQMETHOD=-X POST
set OPT_REQHEADER=-H "Content-Type: application/json;charset=utf-8" -H "Accept: application/json"
set OPT_PROGRESS=-#
set DATA=data
set RESPONSE=response
set STATUS=0
set ERR_MSG=err_msg

rem /*------------------------------------------------------------------------*/
rem /* curl コマンドの存在チェック                                            */
rem /*------------------------------------------------------------------------*/
echo ■■■ curl 存在チェック ■■■ curl コマンドが利用可能かを確認します。
echo.

where curl > nul 2>&1

if not %ERRORLEVEL% == 0 (
    set STATUS=1
    goto PROC_ERROR
)

rem /*------------------------------------------------------------------------*/
rem /* RICHO THETA S との疎通確認                                             */
rem /*------------------------------------------------------------------------*/
echo ■■■ 疎通確認 ■■■ THETA S との通信状態を確認します。
echo.

@echo on
ping -w 5 -n 1 %IP_THETAS%
@echo off

if not %ERRORLEVEL% == 0 (
    set STATUS=2
    goto PROC_ERROR
)

rem /*------------------------------------------------------------------------*/
rem /* RICHO THETA S とのセッション開始                                       */
rem /*     正常終了時の HTTP レスポンス message body (JSON形式)               */
rem /*     { "name":"camera.startSession"                                     */
rem /*      ,"state":"done"                                                   */
rem /*      ,"results":{ "sessionId":"SID_0001"                               */
rem /*                  ,"timeout":180} }                                     */
rem /*------------------------------------------------------------------------*/
echo ■■■ セッション開始 ■■■ THETA S との通信を開始します。
echo.

set DATA=-d "{\"name\":\"camera.startSession\",\"parameters\":{}}"
set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%
for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul
if not %ERRORLEVEL% == 0 (
    set STATUS=3
    goto PROC_ERROR
)

rem /* セッション ID の特定                                                   */
for /f "tokens=3 delims=," %%a in ("%RESPONSE%") do (
    for /f "tokens=3 delims=:" %%b in ("%%a") do set SID=%%~b
)

rem /*------------------------------------------------------------------------*/
rem /* RICHO THETA S の音量調節                                               */
rem /*     正常終了時の HTTP レスポンス message body (JSON形式)               */
rem /*    { "name":"camera.setOptions"                                        */
rem /*     ,"state":"done" }                                                  */
rem /*------------------------------------------------------------------------*/
echo ■■■ 音量調節 ■■■ THETA S の音量を変更します。
echo.

set DATA=-d "{\"name\":\"camera.setOptions\",\"parameters\":{\"sessionId\":\"%SID%\",\"options\":{\"_shutterVolume\":%SHUTTER_VOL%}}}"
set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%
for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul
if not %ERRORLEVEL% == 0 (
    set STATUS=4
    goto PROC_ERROR
)

rem /*------------------------------------------------------------------------*/
rem /* RICHO THETA S とのセッション終了                                       */
rem /*     正常終了時の HTTP レスポンス message body (JSON形式)               */
rem /*    { "name":"camera.closeSession"                                      */
rem /*     ,"state":"done" }                                                  */
rem /*------------------------------------------------------------------------*/
echo ■■■ セッション終了 ■■■ THETA S との通信を終了します。
echo.

set DATA=-d "{\"name\":\"camera.closeSession\",\"parameters\":{\"sessionId\":\"%SID%\"}}"
set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%
for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul
if not %ERRORLEVEL% == 0 (
    set STATUS=5
    goto PROC_ERROR
)

goto END

rem /*------------------------------------------------------------------------*/
rem /* エラー処理                                                             */
rem /*------------------------------------------------------------------------*/
:PROC_ERROR

    echo.

    if %STATUS% == 1 (
        echo ■■■ ERROR ■■■ curl コマンドがみつかりません。curl コマンドがインストールされていることを確認後、PATH を設定してください。
    ) else if %STATUS% == 2 (
        echo ■■■ ERROR ■■■ THETA S と接続されていません。Wi-Fi 設定を確認してください。
    ) else if %STATUS% == 3 (
        echo ■■■ ERROR ■■■ THETA S との接続中にエラーが発生しました。
    ) else if %STATUS% == 4 (
        echo ■■■ ERROR ■■■ THETA S の音量調節に失敗しました。
    ) else if %STATUS% == 5 (
        echo ■■■ ERROR ■■■ THETA S との切断中にエラーが発生しました。
    ) else (
        echo ■■■ ERROR ■■■ Invalid Error.
    )

    echo.
    echo 何かキーを押すとウィンドウを閉じます。
    pause > nul
    exit 1

rem /*------------------------------------------------------------------------*/
rem /* 正常終了                                                               */
rem /*------------------------------------------------------------------------*/
:END
    echo.
    echo ■■■ 正常終了 ■■■ THETA S の音量を %SHUTTER_VOL% に変更しました。
    echo.
    echo 何かキーを押すとウィンドウを閉じます。
    pause > nul
    exit 0

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

@echo off

rem /*========================================================================*/

rem /* ファイル名 : chthetasvol.bat */

rem /* 使用方法 : DOS> chthetasvol.bat */

rem /* コメント : chthetasvol.bat を実行することで RICHO THETA S の */

rem /* シャッター音量を調節できます。 */

rem /* シャッター音量は、下記「変数初期設定」内の「SHUTTER_VOL」 */

rem /* 変数を「0-100」の値で設定します。 */

rem /* (注) chthetasvol.bat の実行には事前に curl のインストール */

rem /* が必要です。 */

rem /*========================================================================*/

rem /*------------------------------------------------------------------------*/

rem /* 変数初期設定 */

rem /* SHUTTER_VOL : シャッター音量（0 [小]-100 [大]) */

rem /* CMD_CURL : curl コマンド */

rem /* IP_THERAS : THETA S の IP アドレス */

rem /* URL : THETA S の HTTP 接続 URL */

rem /* OPT_REQMETHOD : HTTP メソッド(curlオプション) */

rem /* OPT_REQHEADER : HTTP ヘッダー(curlオプション) */

rem /* OPT_PROGRESS : プログレスバー(curlオプション) */

rem /* DATA : HTTP データ(curlオプション) */

rem /* RESPONSE : HTTP レスポンス */

rem /* STATUS : 各処理の状態(0:正常、他:異常) */

rem /* ERR_MSG : エラーメッセージ */

rem /*------------------------------------------------------------------------*/

rem /* お好みのシャッター音量（0 [小]-100 [大]) を設定してください。 */

set SHUTTER_VOL=0

rem /* ここから下は変更不要。 */

set CMD_CURL=curl

set IP_THETAS=192.168.1.1

set URL=http://%IP_THETAS%/osc/commands/execute

set OPT_REQMETHOD=-X POST

set OPT_REQHEADER=-H "Content-Type: application/json;charset=utf-8" -H "Accept: application/json"

set OPT_PROGRESS=-#

set DATA=data

set RESPONSE=response

set STATUS=0

set ERR_MSG=err_msg

rem /*------------------------------------------------------------------------*/

rem /* curl コマンドの存在チェック */

rem /*------------------------------------------------------------------------*/

echo ■■■ curl 存在チェック ■■■ curl コマンドが利用可能かを確認します。

echo.

where curl > nul 2>&1

if not %ERRORLEVEL% == 0 (

set STATUS=1

goto PROC_ERROR

)

rem /*------------------------------------------------------------------------*/

rem /* RICHO THETA S との疎通確認 */

rem /*------------------------------------------------------------------------*/

echo ■■■ 疎通確認 ■■■ THETA S との通信状態を確認します。

echo.

@echo on

ping -w 5 -n 1 %IP_THETAS%

@echo off

if not %ERRORLEVEL% == 0 (

set STATUS=2

goto PROC_ERROR

)

rem /*------------------------------------------------------------------------*/

rem /* RICHO THETA S とのセッション開始 */

rem /* 正常終了時の HTTP レスポンス message body (JSON形式) */

rem /* { "name":"camera.startSession" */

rem /* ,"state":"done" */

rem /* ,"results":{ "sessionId":"SID_0001" */

rem /* ,"timeout":180} } */

rem /*------------------------------------------------------------------------*/

echo ■■■ セッション開始 ■■■ THETA S との通信を開始します。

echo.

set DATA=-d "{\"name\":\"camera.startSession\",\"parameters\":{}}"

set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%

for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul

if not %ERRORLEVEL% == 0 (

set STATUS=3

goto PROC_ERROR

)

rem /* セッション ID の特定 */

for /f "tokens=3 delims=," %%a in ("%RESPONSE%") do (

for /f "tokens=3 delims=:" %%b in ("%%a") do set SID=%%~b

)

rem /*------------------------------------------------------------------------*/

rem /* RICHO THETA S の音量調節 */

rem /* 正常終了時の HTTP レスポンス message body (JSON形式) */

rem /* { "name":"camera.setOptions" */

rem /* ,"state":"done" } */

rem /*------------------------------------------------------------------------*/

echo ■■■ 音量調節 ■■■ THETA S の音量を変更します。

echo.

set DATA=-d "{\"name\":\"camera.setOptions\",\"parameters\":{\"sessionId\":\"%SID%\",\"options\":{\"_shutterVolume\":%SHUTTER_VOL%}}}"

set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%

for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul

if not %ERRORLEVEL% == 0 (

set STATUS=4

goto PROC_ERROR

)

rem /*------------------------------------------------------------------------*/

rem /* RICHO THETA S とのセッション終了 */

rem /* 正常終了時の HTTP レスポンス message body (JSON形式) */

rem /* { "name":"camera.closeSession" */

rem /* ,"state":"done" } */

rem /*------------------------------------------------------------------------*/

echo ■■■ セッション終了 ■■■ THETA S との通信を終了します。

echo.

set DATA=-d "{\"name\":\"camera.closeSession\",\"parameters\":{\"sessionId\":\"%SID%\"}}"

set RESPONSE=response

echo 【実行コマンド】%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%

for /f "usebackq tokens=*" %%a in (`%CMD_CURL% %OPT_PROGRESS% %URL% %OPT_REQMETHOD% %OPT_REQHEADER% %DATA%`) do set RESPONSE=%%a

echo %RESPONSE% | find "done" > nul

if not %ERRORLEVEL% == 0 (

set STATUS=5

goto PROC_ERROR

)

goto END

rem /*------------------------------------------------------------------------*/

rem /* エラー処理 */

rem /*------------------------------------------------------------------------*/

:PROC_ERROR

echo.

if %STATUS% == 1 (

echo ■■■ ERROR ■■■ curl コマンドがみつかりません。curl コマンドがインストールされていることを確認後、PATH を設定してください。

) else if %STATUS% == 2 (

echo ■■■ ERROR ■■■ THETA S と接続されていません。Wi-Fi 設定を確認してください。

) else if %STATUS% == 3 (

echo ■■■ ERROR ■■■ THETA S との接続中にエラーが発生しました。

) else if %STATUS% == 4 (

echo ■■■ ERROR ■■■ THETA S の音量調節に失敗しました。

) else if %STATUS% == 5 (

echo ■■■ ERROR ■■■ THETA S との切断中にエラーが発生しました。

) else (

echo ■■■ ERROR ■■■ Invalid Error.

)

echo.

echo 何かキーを押すとウィンドウを閉じます。

pause > nul

exit 1

rem /*------------------------------------------------------------------------*/

rem /* 正常終了 */

rem /*------------------------------------------------------------------------*/

:END

echo.

echo ■■■ 正常終了 ■■■ THETA S の音量を %SHUTTER_VOL% に変更しました。

echo.

echo 何かキーを押すとウィンドウを閉じます。

pause > nul

exit 0

解凍後のバッチファイルを右クリックして「編集」メニューを選択するとメモ帳でバッチファイルの内容が表示されるので、この中の「set SHUTTER_VOL=0」の値 0 を好きな音量に変更して保存ください。(初期値は 0 (消音)に設定しています)

あとはバッチファイル(chthetasvol.bat)をダブルクリックして実行するだけ！

【実行結果】

theta-s-04-exec-bat

(*) バッチファイルの動作テストは Windows 7 Home Edition の環境でしか行っていませんのでその点ご了承ください。

Windows OS 以外の方や上記バッチファイルでエラーが発生した方は次の手順でシャッター音を調節することができます。

１．コマンドラインターミナルの起動

まず最初に curl コマンドが実行できるコマンドラインターミナルを起動します。

２．セッション開始コマンドの実行

次に、RICOH THETA S とパソコンとのセッションを開始する下記コマンドを実行します。

【実行コマンド】
> curl -# http://192.168.1.1/osc/commands/execute -X POST -H "Content-Type: application/json;charset=utf-8" -H "Accept: application/json" -d "{\"name\":\"camera.startSession\",\"parameters\":{}}"

上記コマンド内のダブルクォーテーション(")のエスケープ文字(\)は、お使いの環境に合わせて変更してください。

３．シャッター音量を調節するコマンドの実行

次に、RICOH THETA S のシャッター音量を変更する下記コマンドを実行します。

このコマンドを実行する前に、コマンド内 sessionId の後にある文字列「SID_0001」は「２．セッション開始コマンドの実行」の実行結果に表示されている sessionId に変更してください。

音量は _shutterVolume の次にある数値「0」を 0 (消音)から 100 (最大)の値で設定してください。

４．セッション終了コマンドの実行

最後に RICOH THETA S とパソコンとのセッションを終了する下記コマンドを実行します。

【実行コマンド】
> curl -# http://192.168.1.1/osc/commands/execute -X POST -H "Content-Type: application/json;charset=utf-8" -H "Accept: application/json" -d "{\"name\":\"camera.closeSession\",\"parameters\":{\"sessionId\":\"SID_0001\"}}"

いかがでしたでしょうか。RICOH THETA S をお持ちの方は音量調節の方法が、お持ちでない方には RICOH THETA S の楽しさ・面白さが伝われば幸いです。

最後に、RICOH THETA S には兄弟分の RICOH THETA という製品もあるのですが、こちらは OSC プロトコルとは異なるプロトコルが使われていますのでこの記事に掲載した方法はご利用いただけません。

この記事に掲載した内容は自己責任のもとご利用いただけますようお願い申し上げます。

Pocket

わたしのおすすめはレシモで共有してます！

地元のおすすめシェアサービス
レシモ (lesimo.jp)

DIY インターネットサービス

RICOH THETA S のシャッター音を消す・調節する方法

RICOH THETA S って何？

RICOH THETA S で撮影した写真や動画

RICOH THETA S の欠点！？

RICOH THETA S 技術的なお話

RICOH THETA S のシャッター音を消す・調節する方法

準備するもの

cURL のダウンロードとインストール

RICOH THETA S とパソコンの接続

RICOH THETA S のシャッター音を消す・調節する

関連する記事

コメントを残すコメントをキャンセル

DIY iLANDS Customer

人気記事RANKING

Categories

SERVICE SUMMARY

DIY iLANDS for WEB

TAGS

Twitter / Facebook

Tweet

PAGES

PAGES

RSS

SEARCH

CATEGORY

DIY インターネットサービス

RICOH THETA S のシャッター音を消す・調節する方法

RICOH THETA S って何？

RICOH THETA S で撮影した写真や動画

RICOH THETA S の欠点！？

RICOH THETA S 技術的なお話

RICOH THETA S のシャッター音を消す・調節する方法

準備するもの

cURL のダウンロードとインストール

RICOH THETA S とパソコンの接続

RICOH THETA S のシャッター音を消す・調節する

関連する記事

コメントを残す コメントをキャンセル

DIY iLANDS Customer

人気記事RANKING

Categories

SERVICE SUMMARY

DIY iLANDS for WEB

TAGS

Twitter / Facebook

Tweet

PAGES

PAGES

RSS

SEARCH

CATEGORY

コメントを残すコメントをキャンセル